% The Computer Modern Text Italic family (by D. E. Knuth, 1979--1985)

mode_setup; font_setup;
%stop "changes?";
%show u,stem_corr,jut,cap_jut,fine,crisp,tiny,asc_height,cap_height,
% fig_height,x_height,bar_height,desc_depth,hair,vair,bar,slab,
% stem,curve,flare,cap_hair,cap_stem,cap_curve,o;

input itall;	% lower case (minuscules)
input italsp;	% lowercase specials (dotless i, ligature ae, etc.)
if ligs>1: font_coding_scheme:="TeX text";
 spanish_shriek=oct"074"; spanish_query=oct"076"; 
 input italig;	% letter ligatures
else: font_coding_scheme:=if ligs>0:"TeX text without f-ligatures"
  else: "TeX typewriter text" fi;
 spanish_shriek=oct"016"; spanish_query=oct"017"; fi

font_slant slant;
if monospace: font_normal_space 9u#; % no stretching or shrinking
 font_xheight x_height#;
 font_quad 18u#;
 font_extra_space 9u#;
 letter_fit#:=letter_fit:=0;
else: font_normal_space 6u#+2letter_fit#;
 font_normal_stretch 3u#; font_normal_shrink 2u#;
 font_xheight x_height#;
 font_quad 18u#+4letter_fit#;
 font_extra_space 2u#; fi

input romanu;	% upper case (majuscules)
input greeku;	% upper case greek letters
input itald;	% numerals
input italp;	% ampersand, question marks, currency sign
input romspu;	% uppercase specials (AE, OE, O/)
input punct;	% punctuation symbols common to roman and italic text
input accent;	% accents common to roman and italic text
if ligs>0: input comlig; fi	% ligatures common with roman text
if ligs≤1: input romsub; fi	% substitutes for ligatures

ligtable "!": "`" =: spanish_shriek;
ligtable "?": "`" =: spanish_query;

if not monospace:
 numeric k,kk,kkk; k=-.5u#; kk=-1.5u#; kkk=-2u#; % three degrees of kerning
 ligtable "d": "w": "l": "l" kern +u#;
 ligtable "F": "V": "A" kern kkk, "o" kern kk, "e" kern kk,
   "a" kern kk, "u" kern kk, "r" kern kk,
  "K": "X": "O" kern k, "C" kern k, "G" kern k, "Q" kern k;
 ligtable "T": "y" kern kk,
  "Y": "o" kern kk, "e" kern kk, "a" kern kk, "u" kern kk, "r" kern kk,
  "P": "W": "A" kern kk;
 ligtable "O": "A" kern k, "W" kern k, "Y" kern k, "V" kern k, "X" kern k;
 ligtable if serifs: "R": fi "A": "t" kern k, "b" kern k, "h" kern k, "k" kern k,
   "l" kern k, "m" kern k, "n" kern k, "r" kern k, "v" kern k, "w" kern k,
  "L": "i" kern k, "u" kern k, "T" kern kk, "O" kern k, "U" kern k, "C" kern k,
   "W" kern kk, "Y" kern kk, "G" kern k, "V" kern kkk, "Q" kern k,
  "b": "c": "e": "o": "p": "r": "a" kern -u#, "c" kern -u#, "d" kern -u#,
   "e" kern -u#, "g" kern -u#, "o" kern -u#, "q" kern -u#;
 ligtable "n": "'" kern kkk; fi
% there are ligature/kern programs for "f" in the romlig file
% and for "-", "`", and "'" in the comlig file

if known Xerox_world: font_family font_identifier;
 coding_scheme font_coding_scheme;
 font_face_byte 254-2 round designsize; fi % Dover code for CM; 154==AM
tracingstats:=10; % temporary
end.